Jump to content

ASUS Zenbook Prime UX31A-DB51 Ultrabook - fixes, mods, tweaks, etc


  • Please log in to reply
982 replies to this topic

#821
kuklins

kuklins

    InsanelyMac Protégé

  • Members
  • Pip
  • 6 posts
  • Gender:Male
  • Location:Moscow, RU

Hi, 68x

I have no USB3 dev's near, but flash, phone and mouse plugged in UX32VD

Attached Files

  • Attached File  MBA.zip   558.13KB   17 downloads


#822
SeppDepp

SeppDepp

    InsanelyMac Protégé

  • Members
  • PipPip
  • 74 posts

I personally would like to use Rehabman's ACPIPoller due to the fact that I can set the method name and the IOProperty; and a huge plus, the code is also documented.

 

Anyways, after testing the below code the fan is silent and quiet. SO far, fan reporting is not possible due to the manual fan control. The below DSDT code allows for a quieter and "efficient" fan (both fans on the UX32VD will be used).

 

Replace your SMCD with:

                Device (SMCD)
                {
                    Name (_HID, "FAN00000")  // _HID: Hardware ID
                    Method (FAN0, 0, NotSerialized)
                    {
                        Store (\_TZ.RFAN (Zero), Local0)
                        Return (Local0)
                    }

                    Method (FAN1, 0, NotSerialized)
                    {
                        Store (\_TZ.RFAN (One), Local0)
                        Return (Local0)
                    }

                    Method (TCPU, 0, Serialized)
                    {
                        Store (^^EC0.ECPU, Local0)
                        Return (Local0)
                    }

                    Method (TIGC, 0, Serialized)
                    {
                        Store (^^EC0.TH0R, Local0)
                        Return (Local0)
                    }

                    Name (TACH, Package (0x04)
                    {
                        "System Fan", 
                        "FAN0", 
                        "GPU Fan", 
                        "FAN1"
                    })
                    Name (FTAB, Buffer (0x12)
                    {
                        /* 0000 */   0x1E, 0x28, 0x28, 0x46, 0x36, 0x50, 0x32, 0x64,
                        /* 0008 */   0x37, 0x73, 0x3C, 0x80, 0x41, 0x96, 0x46, 0xC8,
                        /* 0010 */   0xFF, 0xFF
                    })
                    Name (FHST, Buffer (0x10)
                    {
                        /* 0000 */   0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
                        /* 0008 */   0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00
                    })
                    Name (FIDX, Zero)
                    Name (FNUM, Zero)
                    Name (FSUM, Zero)
                    Name (FLST, 0xFF)
                    Name (FCNT, Zero)
                    Name (FCTU, 0x14)
                    Name (FCTD, 0x28)
                    Name (FSPD, Zero)
                    Name (FANE, Zero)
                    Method (FCPU, 0, Serialized)
                    {
                        Store (One, FANE)
                        Store (TCPU (), Local0)
                        Add (Local0, FSUM, Local1)
                        Store (FIDX, Local2)
                        Subtract (Local1, DerefOf (Index (FHST, Local2)), Local1)
                        Store (Local0, Index (FHST, Local2))
                        Store (Local1, FSUM)
                        Increment (Local2)
                        If (LGreaterEqual (Local2, SizeOf (FHST)))
                        {
                            Store (Zero, Local2)
                        }

                        Store (Local2, FIDX)
                        Store (FNUM, Local2)
                        If (LNotEqual (Local2, SizeOf (FHST)))
                        {
                            Increment (Local2)
                            Store (Local2, FNUM)
                        }

                        Divide (Local1, Local2, , Local0)
                        If (LGreater (Local0, 0xFF))
                        {
                            Store (0xFF, Local0)
                        }

                        Store (Zero, Local2)
                        While (LGreater (Local0, DerefOf (Index (FTAB, Local2))))
                        {
                            Add (Local2, 0x02, Local2)
                        }

                        If (LGreater (Local2, FLST))
                        {
                            Subtract (Local2, FLST, Local1)
                            Store (FCTU, Local4)
                        }
                        Else
                        {
                            Subtract (FLST, Local2, Local1)
                            Store (FCTD, Local4)
                        }

                        If (LEqual (Local1, Zero))
                        {
                            Store (Zero, FCNT)
                        }
                        Else
                        {
                            Store (FCNT, Local3)
                            Increment (Local3)
                            Store (Local3, FCNT)
                            Divide (ShiftLeft (Local4, One), Local1, , Local1)
                            If (LGreaterEqual (Local3, Local1))
                            {
                                Store (Local2, FLST)
                                Increment (Local2)
                                Store (DerefOf (Index (FTAB, Local2)), FSPD)
                                ^^EC0.SFNV (One, FSPD)
                                ^^EC0.SFNV (0x02, FSPD)
                                Store (Zero, FCNT)
                            }
                        }

                        Return (Local0)
                    }

                    Method (TCPP, 0, Serialized)
                    {
                        Store (FNUM, Local0)
                        If (LNotEqual (Local0, Zero))
                        {
                            Store (FSUM, Local1)
                            Divide (Local1, Local0, , Local0)
                        }

                        Return (Local0)
                    }

                    Method (TSYS, 0, Serialized)
                    {
                        Return (FCNT)
                    }
                }

Replace SFNV:

        Name (DEC1, Zero)
        Name (DEC2, Zero)
        Method (SFNV, 2, Serialized)
        {
            If (LEqual (Arg0, Zero))
            {
                If (LEqual (DEC1, One))
                {
                    Store (RRAM (0x0521), Local0)
                    Or (Local0, 0x80, Local0)
                    WRAM (0x0521, Local0)
                }

                If (LEqual (DEC2, One))
                {
                    Store (RRAM (0x0522), Local0)
                    Or (Local0, 0x80, Local0)
                    WRAM (0x0522, Local0)
                }

                Store (Zero, DEC1)
                Store (Zero, DEC2)
                Return (Zero)
            }

            If (LEqual (Arg0, One))
            {
                Store (RRAM (0x0521), Local0)
                And (Local0, 0x7F, Local0)
                WRAM (0x0521, Local0)
                Store (One, DEC1)
                ST84 (Zero, Arg1)
                Return (Zero)
            }

            If (LEqual (Arg0, 0x02))
            {
                Store (RRAM (0x0522), Local0)
                And (Local0, 0x7F, Local0)
                WRAM (0x0522, Local0)
                Store (One, DEC2)
                ST84 (One, Arg1)
                Return (Zero)
            }

            Return (Zero)
        }

I added support to make both fans go automatic.

 

Add this to _PTS:

            If (\_SB.PCI0.LPCB.SMCD.FANE)
            {
                \_SB.PCI0.LPCB.EC0.SFNV (Zero, Zero)
            }

This will shut the fans off before going to sleep by putting in "Auto Mode".

 

Again, this is for the UX32VD and use at your own risk.

 

Hi 68x... I'm trying to get fan control to work. Right now it changes the fan control behavior (starts with maximum fan, fan never stops even when it is around 45C. Normally stops on bios/auto mode. HWMonitor shows 35rpm for cpu and gpu fan.).

 

It seems it is kind of working, since the behavior is changed. (I put SMCD device in \_SB.PCI0.LPCB.SMCD).

 

There are comments/documentation for the SFNV methode (http://forum.noteboo...32a-ux32vd.html):

Name (DECF, Zero) // stores which fans were set to manual control, for later resetting back to auto
Method (SFNV, 2, Serialized)
{
    If (LEqual (Arg0, Zero))
    {
        If (And (DECF, One)) // reset Fan1 back to Auto speed control
        {
            Store (RRAM (0x0521), Local0)
            Or (Local0, 0x80, Local0)
            WRAM (0x0521, Local0) // 0x8d auto ON/OFF
        }

        If (And (DECF, 0x02)) // reset Fan2 back to Auto speed control
        {
            Store (RRAM (0x0522), Local0)
            Or (Local0, 0x80, Local0)
            WRAM (0x0522, Local0) // 0x8e auto ON/OFF
        }

        Store (Zero, DECF)
        Return (Zero)
    }

    If (LEqual (Arg0, One)) // set fan speed manually for Fan1
    {
        Store (RRAM (0x0521), Local0)
        And (Local0, 0x7F, Local0)
        WRAM (0x0521, Local0) // 0xd manually set
        Or (DECF, One, DECF)
        ST84 (Zero, Arg1)
        Return (Zero)
    }

    If (LEqual (Arg0, 0x02)) // set fan speed manually for Fan2
    {
        Store (RRAM (0x0522), Local0)
        And (Local0, 0x7F, Local0)
        WRAM (0x0522, Local0) // 0xe manually set
        Or (DECF, 0x02, DECF)
        ST84 (One, Arg1)
        Return (Zero)
    }

    Return (Zero)
}

Is there any documentation/comments for the SMCD device code?



#823
Ramalama

Ramalama

    InsanelyMac Sage

  • Members
  • PipPipPipPipPip
  • 260 posts
  • Gender:Not Telling
  • Location:Germany
Fan Max Speed: 6500 RP/min
0xFF = 255
6500 / 255 = ~25,5

\_SB.PCI0.LPCB.EC0.SFNV 1 0x7D //set Fan0 speed to 0x7D
----> 0x7D = 125 ---> 125 x 25,5 = 3187,5 RP/min

\_SB.PCI0.LPCB.EC0.SFNV 2 0x00 //set Fan1 speed to 0x00
----> 0x00 = 0 ----> OFF

\_SB.PCI0.LPCB.EC0.SFNV 0 0   //Set ALL Fans to Automatic
\_SB.PCI0.LPCB.EC0.SFNV 0 1   //Set Fan1 to Automatic
\_SB.PCI0.LPCB.EC0.SFNV 0 2   //Set Fan2 to Automatic

NOTE: In Manual mode, you can't read out Fan Speed!!
----> Thats why we Mutiply our Custom setted Speed with 25,5 !!!

\_SB.PCI0.LPCB.EC0.TACH (Zero)  // Read current FAN1 Speed in RP/min
\_SB.PCI0.LPCB.EC0.TACH (One)   // Read current FAN2 Speed in RP/min
Device (SMCD)
    {
        Name (_HID, "FAN00000") // Just for FakeSMC, that it knows what to look for!
                                // Can be MON00000 or other, see inside FakeSMC info.plist
        Name (TACH, Package (0x04) // This is description for FAN's
        {
            "Left Fan", "FAN1",   // "ANY NAME", "Any Method Name",
            "Right Fan", "FAN0"   // Example: "My Ass Megafan", "MSMF"
        })

        Method (FAN0, 0, NotSerialized)  // FAN0 = Right Fan, as wrote on top!
        {
            Store (\_SB.PCI0.LPCB.EC0.TACH (Zero), Local0) //Store FAN0 RPm in Local0 Variable
            Return (Local0)  // Returns the Variable (Rpm) for FakeSMC
        }

        Method (FAN1, 0, NotSerialized) // FAN1 = Left Fan, as described on top...
        {
            Store (\_SB.PCI0.LPCB.EC0.TACH (One), Local0) // Store FAN1 into Local0 Variable
            Return (Local0) // Returns the Variable (Rpm) for FakeSMC
        }
        Name (KLVN, Zero)   // Not use Kelvins (Celsius instead) 
        Name (TEMP, Package (0x0C) // Description Package "Temperature" for FakeSMC
        {
            "CPU Heatsink", "TCPU",   // "Custom Name", "linked Method",
            "CPU Proximity", "TCPP", 
            "PCH Die", "TPCH", 
            "Mainboard", "TSYS",
            "Passive Cooling", "CPCT",
            "Critical Temp", "CPTM"
        })
        Method (TCPU, 0, NotSerialized)  // The rest is same like on top...
        {
            Store (\_SB.PCI0.LPCB.EC0.ECPU, Local0)
            Return (Local0)
        }
        Method (TCPP, 0, NotSerialized)
        {
            Store (\_SB.PCI0.LPCB.EC0.TH0R, Local0)
            Return (Local0)
        }
        Method (TPCH, 0, NotSerialized)
        {
            Store (\_SB.PCI0.LPCB.EC0.TH1L, Local0)
            Return (Local0)
        }
        Method (TSYS, 0, NotSerialized)
        {
            Store (\_SB.PCI0.LPCB.EC0.TH1R, Local0)
            Return (Local0)
        }
        Method (CPCT, 0, NotSerialized)
        {
            Store (\_SB.PCI0.LPCB.EC0.EPSV, Local0)
            Return (Local0)
        }
        Method (CPTM, 0, NotSerialized)
        {
            Store (\_SB.PCI0.LPCB.EC0.ECRT, Local0)
            Return (Local0)
        }
    }

Device (PROB) // Polling Device name for FakeSMC, The Methods here are executed every
              // 1/2/3/whatever second!
    {
        Name (_HID, EisaId ("PNP0C02")) // Expose PLLD to IORegistry
        Name (_CID, EisaId ("PRB0000")) // device compatible name allows ACPIProbe matching
        Name (INVL, 0x3E8)          // Set Polling interval 1 sec
        Name (TOUT, Zero)           // Set Polling timeout  0 sec (continuous polling)
        Name (LOGG, One)            // Enable Console logging of values returned by methods
        Name (LIST, Package (One)   // Define methods to poll
        { "SFNS" })
        
        Method (SFNS, 0, NotSerialized)
        {
            Store (\_SB.PCI0.LPCB.EC0.ECPU, Local0)      // Get current CPU Temperature
            If (LLessEqual (Local0, 0x32)) {             // If CPU is < 50C, disable both Fans
                \_SB.PCI0.LPCB.EC0.SFNV (One, Zero)    // Set FAN0 OFF
                \_SB.PCI0.LPCB.EC0.SFNV (0x02, Zero)   // Set FAN1 OFF
                Store ("Fans are OFF", Local1) } Else {  // Store "Fans are OFF" for Logging output
                \_SB.PCI0.LPCB.EC0.SFNV (Zero, Zero)     // If CPU is > 50C, set to Automatic
                Store ("Fans are AUTO", Local1) }  // Store Fans are AUTO for log output...
            Return (Local1)  // Return for FakeSMC Logging
        }
    }

FakeSMC is not good described... there are no WIKI, nothing... Its all searched together... 

But here you have something to start with!

 

Cheers :-)



#824
SeppDepp

SeppDepp

    InsanelyMac Protégé

  • Members
  • PipPip
  • 74 posts
Fan Max Speed: 6500 RP/min
0xFF = 255
6500 / 255 = ~25,5

\_SB.PCI0.LPCB.EC0.SFNV 1 0x7D //set Fan0 speed to 0x7D
----> 0x7D = 125 ---> 125 x 25,5 = 3187,5 RP/min

\_SB.PCI0.LPCB.EC0.SFNV 2 0x00 //set Fan1 speed to 0x00
----> 0x00 = 0 ----> OFF

\_SB.PCI0.LPCB.EC0.SFNV 0 0   //Set ALL Fans to Automatic
\_SB.PCI0.LPCB.EC0.SFNV 0 1   //Set Fan1 to Automatic
\_SB.PCI0.LPCB.EC0.SFNV 0 2   //Set Fan2 to Automatic

NOTE: In Manual mode, you can't read out Fan Speed!!
----> Thats why we Mutiply our Custom setted Speed with 25,5 !!!

\_SB.PCI0.LPCB.EC0.TACH (Zero)  // Read current FAN1 Speed in RP/min
\_SB.PCI0.LPCB.EC0.TACH (One)   // Read current FAN2 Speed in RP/min
Device (SMCD)
    {
        Name (_HID, "FAN00000") // Just for FakeSMC, that it knows what to look for!
                                // Can be MON00000 or other, see inside FakeSMC info.plist
        Name (TACH, Package (0x04) // This is description for FAN's
        {
            "Left Fan", "FAN1",   // "ANY NAME", "Any Method Name",
            "Right Fan", "FAN0"   // Example: "My Ass Megafan", "MSMF"
        })

        Method (FAN0, 0, NotSerialized)  // FAN0 = Right Fan, as wrote on top!
        {
            Store (\_SB.PCI0.LPCB.EC0.TACH (Zero), Local0) //Store FAN0 RPm in Local0 Variable
            Return (Local0)  // Returns the Variable (Rpm) for FakeSMC
        }

        Method (FAN1, 0, NotSerialized) // FAN1 = Left Fan, as described on top...
        {
            Store (\_SB.PCI0.LPCB.EC0.TACH (One), Local0) // Store FAN1 into Local0 Variable
            Return (Local0) // Returns the Variable (Rpm) for FakeSMC
        }
        Name (KLVN, Zero)   // Not use Kelvins (Celsius instead) 
        Name (TEMP, Package (0x0C) // Description Package "Temperature" for FakeSMC
        {
            "CPU Heatsink", "TCPU",   // "Custom Name", "linked Method",
            "CPU Proximity", "TCPP", 
            "PCH Die", "TPCH", 
            "Mainboard", "TSYS",
            "Passive Cooling", "CPCT",
            "Critical Temp", "CPTM"
        })
        Method (TCPU, 0, NotSerialized)  // The rest is same like on top...
        {
            Store (\_SB.PCI0.LPCB.EC0.ECPU, Local0)
            Return (Local0)
        }
        Method (TCPP, 0, NotSerialized)
        {
            Store (\_SB.PCI0.LPCB.EC0.TH0R, Local0)
            Return (Local0)
        }
        Method (TPCH, 0, NotSerialized)
        {
            Store (\_SB.PCI0.LPCB.EC0.TH1L, Local0)
            Return (Local0)
        }
        Method (TSYS, 0, NotSerialized)
        {
            Store (\_SB.PCI0.LPCB.EC0.TH1R, Local0)
            Return (Local0)
        }
        Method (CPCT, 0, NotSerialized)
        {
            Store (\_SB.PCI0.LPCB.EC0.EPSV, Local0)
            Return (Local0)
        }
        Method (CPTM, 0, NotSerialized)
        {
            Store (\_SB.PCI0.LPCB.EC0.ECRT, Local0)
            Return (Local0)
        }
    }

Device (PROB) // Polling Device name for FakeSMC, The Methods here are executed every
              // 1/2/3/whatever second!
    {
        Name (_HID, EisaId ("PNP0C02")) // Expose PLLD to IORegistry
        Name (_CID, EisaId ("PRB0000")) // device compatible name allows ACPIProbe matching
        Name (INVL, 0x3E8)          // Set Polling interval 1 sec
        Name (TOUT, Zero)           // Set Polling timeout  0 sec (continuous polling)
        Name (LOGG, One)            // Enable Console logging of values returned by methods
        Name (LIST, Package (One)   // Define methods to poll
        { "SFNS" })
        
        Method (SFNS, 0, NotSerialized)
        {
            Store (\_SB.PCI0.LPCB.EC0.ECPU, Local0)      // Get current CPU Temperature
            If (LLessEqual (Local0, 0x32)) {             // If CPU is < 50C, disable both Fans
                \_SB.PCI0.LPCB.EC0.SFNV (One, Zero)    // Set FAN0 OFF
                \_SB.PCI0.LPCB.EC0.SFNV (0x02, Zero)   // Set FAN1 OFF
                Store ("Fans are OFF", Local1) } Else {  // Store "Fans are OFF" for Logging output
                \_SB.PCI0.LPCB.EC0.SFNV (Zero, Zero)     // If CPU is > 50C, set to Automatic
                Store ("Fans are AUTO", Local1) }  // Store Fans are AUTO for log output...
            Return (Local1)  // Return for FakeSMC Logging
        }
    }

FakeSMC is not good described... there are no WIKI, nothing... Its all searched together... 

But here you have something to start with!

 

Cheers :-)

 

 

Thanks Ramalama!

 

I see, there are two different concepts to call the SFNV method. 1.) code inside SMCD with ACPIPoller 2.) "PROB" device with ACPIProbe

 

I just was asking, because I don't understand the logic inside 68x's SMCD device.

 

The logic should be something like some up-thresholds for faster fan speed and some down-thresholds for lowering fan speed.

 

Like maybe:

Up-Threshold  Down-Threshold Fan-Speed

0C                       0C                          0%

60C                     45C                        10%

65C                     55C                         25%

67C                     59C                         40%

...



#825
Ramalama

Ramalama

    InsanelyMac Sage

  • Members
  • PipPipPipPipPip
  • 260 posts
  • Gender:Not Telling
  • Location:Germany

Its simple, you can do easily the code yourself... just use \_SB.PCI0.LPCB.EC0.ECPU to get the temperature you want and SFNV to set your custom Rpm Speed...

 

the "\_SB.PCI0.LPCB.EC0.ECPU" you get is always temperature in Celsius and hex format, 0x32 = 50°C for example...

 

just use something like this, and define yourself how you want the thermal working:

 

Store (\_SB.PCI0.LPCB.EC0.ECPU, Local0) // Store current Celsius Temperature °C in Local0 Variable

If (LLessEqual (Local0, 0x32)) { // If less as 50°C and 50°C do:

\_SB.PCI0.LPCB.EC0.SFNV (One, Zero) //FAN0 to OFF

\_SB.PCI0.LPCB.EC0.SFNV (0x02, Zero) //FAN1 to OFF

}

If (LOr( LGreater(Local0,0x32), LLessEgual(Local0,0x3C))) { // If greater as 50°C and Less as 60°C and 60°C do this:

\_SB.PCI0.LPCB.EC0.SFNV (One0x64) //FAN0 to 0x64(100) --> 100 x 25,5 = 2550 RPm

\_SB.PCI0.LPCB.EC0.SFNV (0x02, 0x8C) //FAN1 to 0x8C(140) --> 140 x 25,5 = 3570 RPm

 

}

If .... Whatever you want...

 

 

Its really simple... nothing special :-)

 

Do your own code, and be happy :-)

 

---------

 

PS: Sry, maybe i misunderstood you, what you mean with threshold?

 

If you want it more continuous, you can just multiply CPU temperature with Fan Speed values...

It's simple too, i can explain it if you want...

 

Cheers :-)



#826
berny_

berny_

    InsanelyMac Geek

  • Members
  • PipPipPipPip
  • 246 posts
  • Gender:Male
Hi, there is a way to enable SD card reader? Can I buy anorher compatible with osx? if there is which one?

Thank

#827
Ramalama

Ramalama

    InsanelyMac Sage

  • Members
  • PipPipPipPipPip
  • 260 posts
  • Gender:Not Telling
  • Location:Germany

if you have alcor card reader it should work :-) its just invisible, till you plug a card in :-)



#828
P5QMac

P5QMac

    InsanelyMac Protégé

  • Members
  • Pip
  • 28 posts

Hi, there is a way to enable SD card reader? Can I buy anorher compatible with osx? if there is which one?

Thank

 

I've tried looking for some solution to this problem, but alas it seems to not be possible at this point in time. We have a Realtek Internal SD Card reader with productID: 0x0139 (313) and VendorID: 0x0bda (3034). It appears as USB2.0-CRW in the USB section of System Information. You can cosmetically rename it into a "Internal Memory Card Reader" by using AnyCardReader.kext, but the slot itself will not work. Editing the AppleUSBCardReader kext doesn't help unfortunately.

 

Luckily SD card readers are cheap and easy to use, so I'd recommend something like a Kingston FCR-HS3 (USB3 speeds) for example which is really nice. Or you can find something more portable probably on eBay or your local store. Most of them are compatible with OS X OOB. 



#829
berny_

berny_

    InsanelyMac Geek

  • Members
  • PipPipPipPip
  • 246 posts
  • Gender:Male

Thank for your answer, is possible change the internal card reader with another not external but internal?



#830
Ramalama

Ramalama

    InsanelyMac Sage

  • Members
  • PipPipPipPipPip
  • 260 posts
  • Gender:Not Telling
  • Location:Germany

Maybe its possible, but i don't think you will find it to buy anywhere :-)

 

Just as a repair part somewhere, but you need to look if its from alcor...

 

Cheers :-)



#831
P5QMac

P5QMac

    InsanelyMac Protégé

  • Members
  • Pip
  • 28 posts

Apple released 10.9.2 which is a crucial update due to a dangerous security flaw. 

 

It has updates to the sound drivers and the graphics drivers. Thus the GeForce drivers will reappear and the Intel driver will be overwritten with newer ones. Plus the AppleHDA will be overwritten.

 

I tried with HDMI audio with the stock kext and it did not work, so here's the fresh 10.9.2 AppleIntelFramebufferCapri edited for HDMI audio (UX32VD). Tested and working perfectly fine. Enjoy!

Attached Files



#832
Ramalama

Ramalama

    InsanelyMac Sage

  • Members
  • PipPipPipPipPip
  • 260 posts
  • Gender:Not Telling
  • Location:Germany

Or if you are using Clover, you can simply use my patch:

 

Hdmi Audio:

https://github.com/R...udio-HD4000.txt

 

ALC269 / 270 / 282:

https://github.com/R...r/2. Clover ALC

 

@P5QMac

Is your Sleep working after 10.9.2 Update? :-)

 

My Sleep doesn't like me and gone away xD



#833
P5QMac

P5QMac

    InsanelyMac Protégé

  • Members
  • Pip
  • 28 posts

@P5QMac

Is your Sleep working after 10.9.2 Update? :-)

 

My Sleep doesn't like me and gone away xD

 

Yup, sleep working fine and audio works fine after sleep as well. I'm using Chameleon though, so that might be the reason, as I think 68x had problems with sleep as well according to:

 

Here is my config.plist. Do not use it without reading the Clover wiki.

You have been warned (there are some sleep issues that I am still trying to diagnose).



#834
Ramalama

Ramalama

    InsanelyMac Sage

  • Members
  • PipPipPipPipPip
  • 260 posts
  • Gender:Not Telling
  • Location:Germany

Yup, sleep working fine and audio works fine after sleep as well. I'm using Chameleon though, so that might be the reason, as I think 68x had problems with sleep as well according to:

 

I tryed Chameleon already :-)

There is no difference, for some there is difference but the most of them doesnt know how to use Clover...

Clover have very much options for sleep and more...

 

However, My Sleep is working with 10.9.1, with Clover and Chameleon, and since the first beta of 10.9.2 + now the official 10.9.2, it just reboots on wake :-)

With both, Clover and Chameleon... :-)

 

However, i spoken already with 68x, he knows not more as i, and i don't know more as he :-)

 

 

Im just confused why so much ppl are using Chameleon with an uefi board, and not Clover... were you don't need to patch anymore anything... like applehda on every update... And the other example is, Im booting with Clover twice as fast, as with chameleon... Clover is taking 6-8 Secounds to OSX login... and Chameleon takes for the same 14-18 seconds...

 

 

However :-) Seems like i need to experiment little bit more, or start to debug the kernel... But i already know where it comes from... thats the new Drivers from 10.9.2... For the Iris 5100...

But however, i need to debug, to find out where it exactly comes from... Maybe its fixable with dsdt... Will see :-)

 

 

Thank you P5QMac :-)



#835
ammor

ammor

    InsanelyMac Protégé

  • Members
  • Pip
  • 13 posts
  • Gender:Male
  • Location:China

I've Uploaded UX32A Dsdt, to my github...

 

I need anyone with a UX31A, im going to support this model too :-)

And who know already the base things, and have osx already running :-)

 

Cheers :-)

Let me know what you need, I have a UX31A-DH51 running OSX 10.9.2 :-)



#836
Ramalama

Ramalama

    InsanelyMac Sage

  • Members
  • PipPipPipPipPip
  • 260 posts
  • Gender:Not Telling
  • Location:Germany

Let me know what you need, I have a UX31A-DH51 running OSX 10.9.2 :-)

---> All your Tables exported from Clover (Hit in Clover "F4" Key / "Efi/Clover/ACPI/origin" Folder)

---> Aida64 Report.html (Windows)

---> And maybe a codec_dump from linux (but this we going to see later, maybe there exists some with 164bit Patched Verbs)

---> And a list of the UX31A Versions, (Only the differences related to GPU and CPU)

 

Thats all :-)



#837
68x

68x

    InsanelyMac Geek

  • Members
  • PipPipPip
  • 162 posts

Let me know what you need, I have a UX31A-DH51 running OSX 10.9.2 :-)

 

Everything you need IS in this thread. All you need to do is just read and search. The main post explains everything you need to create an USB installer.



#838
kuklins

kuklins

    InsanelyMac Protégé

  • Members
  • Pip
  • 6 posts
  • Gender:Male
  • Location:Moscow, RU

 

My Sleep doesn't like me and gone away xD

 

My sleep almost gone away -) , i've freeze sometimes with menu sleep and autosleep, but no reboots.



#839
Ramalama

Ramalama

    InsanelyMac Sage

  • Members
  • PipPipPipPipPip
  • 260 posts
  • Gender:Not Telling
  • Location:Germany

@68x

 

I wrote:

I've Uploaded UX32A Dsdt, to my github...
 
I need anyone with a UX31A, im going to support this model too :-)
And who know already the base things, and have osx already running :-)
 
Cheers :-) 

He Answered:

 

Let me know what you need, I have a UX31A-DH51 running OSX 10.9.2 :-)

I Answered what i need:

 

---> All your Tables exported from Clover (Hit in Clover "F4" Key / "Efi/Clover/ACPI/origin" Folder)

---> Aida64 Report.html (Windows)

---> And maybe a codec_dump from linux (but this we going to see later, maybe there exists some with 164bit Patched Verbs)

---> And a list of the UX31A Versions, (Only the differences related to GPU and CPU)

 

Thats all :-)

----------------------

How you easily can see here, is, that I HAVE REQUESTED files from UX31A! To Support this model in my Github!

And he have osx already running and asked me what i need!

 

So your Post here makes no sense:

 

Everything you need IS in this thread. All you need to do is just read and search. The main post explains everything you need to create an USB installer.

 

 

Cheers :-)


My sleep almost gone away -) , i've freeze sometimes with menu sleep and autosleep, but no reboots.

Im Going to debug this next week with 2 osx machines :-)

 

I will post, what i found out :-)

 

Cheers :-)



#840
Voskot

Voskot

    InsanelyMac Protégé

  • Members
  • Pip
  • 14 posts
  • Gender:Male
  • Location:Italy
Hello everyone, 
I have a problem with audio after updating to 10.9.2: no audio output from headphones.
The speaker works fine but when I connect the headphones the system recognizes them but there's no audio coming out.
 
I'm using AppleHDA.kext v2.6.0 vanilla, but patched with clover with these for ALC269 (without the other kext AppleHDA269.kext). FixHDA_8000 is set to true in clover. I tried with the DSDT I was already using and with the one found on GitHub here.
Everything else on my hackintosh works fine included sleep, even with 10.9.2.
 
My Laptop:
ASUS UX32A, BIOS 215
Intel i3-3217U
ALC269VB
 
Attached: both DSDT, CodecCommander kext, audio codec dump, AppleHDA right after 10.9.2 update and ioreg (done with the dsdt from github, I don't know if matters). I don't know if there's something else I should have attached.
 
 
Thank you everyone for your help and for everything you've done and shared on this forum and in other places! 
 

Attached Files







0 user(s) are reading this topic

0 members, 0 guests, 0 anonymous users

© 2014 InsanelyMac  |   News  |   Forum  |   Downloads  |   OSx86 Wiki  |   Mac Netbook  |   PHP hosting by CatN  |   Designed by Ed Gain  |   Logo by irfan  |   Privacy Policy